71 lines
2.4 KiB
Nix
71 lines
2.4 KiB
Nix
# SPDX-FileCopyrightText: 2003-2020 Nixpkgs/NixOS contributors
|
|
#
|
|
# SPDX-License-Identifier: MIT
|
|
|
|
{ lib, stdenv, fetch, cmake, python, libcxxabi, fixDarwinDylibNames, version
|
|
, enableShared ? true }:
|
|
|
|
let
|
|
enableShared' = if enableShared then !stdenv.hostPlatform.isGenode else false;
|
|
in
|
|
stdenv.mkDerivation rec {
|
|
pname = "libc++";
|
|
inherit version;
|
|
|
|
src = fetch "libcxx" "0y4vc9z36c1zlq15cnibdzxnc1xi5glbc6klnm8a41q3db4541kz";
|
|
|
|
postUnpack = ''
|
|
unpackFile ${libcxxabi.src}
|
|
export LIBCXXABI_INCLUDE_DIR="$PWD/$(ls -d libcxxabi-${version}*)/include"
|
|
'';
|
|
|
|
patches = with stdenv.hostPlatform; []
|
|
++ stdenv.lib.optional isMusl ../../libcxx-0001-musl-hacks.patch
|
|
++ stdenv.lib.optional isGenode ./genode.patch;
|
|
|
|
prePatch = ''
|
|
substituteInPlace lib/CMakeLists.txt --replace "/usr/lib/libc++" "\''${LIBCXX_LIBCXXABI_LIB_PATH}/libc++"
|
|
'';
|
|
|
|
preConfigure = ''
|
|
# Get headers from the cxxabi source so we can see private headers not installed by the cxxabi package
|
|
cmakeFlagsArray=($cmakeFlagsArray -DLIBCXX_CXX_ABI_INCLUDE_PATHS="$LIBCXXABI_INCLUDE_DIR")
|
|
'' + lib.optionalString stdenv.hostPlatform.isMusl ''
|
|
patchShebangs utils/cat_files.py
|
|
'';
|
|
nativeBuildInputs = [ cmake ]
|
|
++ stdenv.lib.optional (with stdenv.hostPlatform; (isMusl || isWasi || isGenode)) python;
|
|
|
|
buildInputs = [ libcxxabi ] ++ lib.optional stdenv.isDarwin fixDarwinDylibNames;
|
|
|
|
cmakeFlags = [
|
|
"-DLIBCXX_LIBCXXABI_LIB_PATH=${libcxxabi}/lib"
|
|
"-DLIBCXX_LIBCPPABI_VERSION=2"
|
|
"-DLIBCXX_CXX_ABI=libcxxabi"
|
|
] ++ stdenv.lib.optional (stdenv.hostPlatform.isMusl || stdenv.hostPlatform.isWasi) "-DLIBCXX_HAS_MUSL_LIBC=1"
|
|
++ stdenv.lib.optional (stdenv.hostPlatform.useLLVM or false) "-DLIBCXX_USE_COMPILER_RT=ON"
|
|
++ stdenv.lib.optional stdenv.hostPlatform.isGenode
|
|
"-DLIBCXX_ENABLE_THREADS=OFF"
|
|
++ stdenv.lib.optional stdenv.hostPlatform.isWasm [
|
|
"-DLIBCXX_ENABLE_THREADS=OFF"
|
|
"-DLIBCXX_ENABLE_FILESYSTEM=OFF"
|
|
"-DLIBCXX_ENABLE_EXCEPTIONS=OFF"
|
|
] ++ stdenv.lib.optional (!enableShared') "-DLIBCXX_ENABLE_SHARED=OFF";
|
|
|
|
enableParallelBuilding = true;
|
|
|
|
linkCxxAbi = stdenv.isLinux;
|
|
|
|
setupHooks = [
|
|
./role.bash
|
|
./setup-hook.sh
|
|
];
|
|
|
|
meta = {
|
|
homepage = http://libcxx.llvm.org/;
|
|
description = "A new implementation of the C++ standard library, targeting C++11";
|
|
license = with stdenv.lib.licenses; [ ncsa mit ];
|
|
platforms = stdenv.lib.platforms.all;
|
|
};
|
|
}
|