let Genode = env:DHALL_GENODE

let Prelude = Genode.Prelude

let Init = Genode.Init

let Child = Init.Child

let Config = Init.Config

let toSimple =
      λ(testName : Text) →
        Child.flat
          Child.Attributes::{
          , binary = "solo5-test_${testName}"
          , resources = Init.Resources::{ caps = 256, ram = Genode.units.MiB 3 }
          , config = Config::{
            , content =
              [ Prelude.XML.element
                  { name = "cmdline"
                  , attributes = Prelude.XML.emptyAttributes
                  , content = [ Prelude.XML.text "Hello_Solo5" ]
                  }
              ]
            }
          }

in  λ(params : { isAarch64 : Bool }) →
      let children =
              toMap
                { quiet = toSimple "quiet"
                , hello = toSimple "hello"
                , globals = toSimple "globals"
                , time = ./time.dhall
                , blk = ./blk.dhall
                , net = ./net.dhall
                , net_2if = ./net_2if.dhall
                }
            # ( if    params.isAarch64
                then  Prelude.Map.empty Text Child.Type
                else  toMap { fpu = toSimple "fpu" }
              )

      in  Init.Child.nested
            children
            Init.Child.Attributes::{
            , binary = "sequence"
            , routes =
              [ Init.ServiceRoute.parent "Timer"
              , Init.ServiceRoute.parent "Rtc"
              ]
            }