# SPDX-FileCopyrightText: Emery Hemingway
#
# SPDX-License-Identifier: LicenseRef-Hippocratic-1.1

{ stdenvNoCC, fetchurl }:

let
  stdenv = stdenvNoCC;
  unpack = { name, value }: {
    inherit name;
    value = stdenv.mkDerivation {
      pname = name;
      inherit (value) version;
      preferLocalBuild = true;
      src = fetchurl {
        url =
          "http://depot.genode.org/genodelabs/bin/x86_64/${name}/${value.version}.tar.xz";
        inherit (value) sha256;
      };
      phases = [ "unpackPhase" "installPhase" "fixupPhase" "distPhase" ];
      installPhase = ''
        find . -type f | while read FILE; do
          local DEST=$out/bin
          case $FILE in
            *.a) DEST=$out/lib ;;
            *.o) DEST=$out/lib ;;
            *.so) DEST=$out/lib ;;
            *.tar) DEST=$out/tar ;;
          esac
          install -Dm444 -t $DEST $FILE
        done
      '';
      meta = {
        license = [ "LicenseRef-Genode" ];
        downloadPage = "http://depot.genode.org/genodelabs/bin/x86_64/${name}/";
        maintainers = with stdenv.lib.maintainers; [ ehmry ];
      };
    };
  };

  listing = import ./list.nix;
  derivations = map unpack listing;
in builtins.listToAttrs derivations