-- SPDX-License-Identifier: CC0-1.0

let Test = ../test.dhall ? env:DHALL_GENODE_TEST

let Genode = Test.Genode

let Prelude = Genode.Prelude

let Init = Genode.Init

let Child = Init.Child

let Config = Init.Config

let toSimple =
        λ(testName : Text)
      → Child.flat
          Child.Attributes::{
          , binary = "solo5-test_${testName}"
          , resources = Init.Resources::{ caps = 256, ram = Genode.units.MiB 3 }
          , config = Config::{
            , content =
              [ Prelude.XML.element
                  { name = "cmdline"
                  , attributes = Prelude.XML.emptyAttributes
                  , content = [ Prelude.XML.text "Hello_Solo5" ]
                  }
              ]
            }
          , routes = [ Init.ServiceRoute.parent "Timer" ]
          }

let tests
    : Prelude.Map.Type Text Child.Type
    = [ { mapKey = "quiet", mapValue = toSimple "quiet" }
      , { mapKey = "hello", mapValue = toSimple "hello" }
      , { mapKey = "globals", mapValue = toSimple "globals" }
      , { mapKey = "fpu", mapValue = toSimple "fpu" }
      , { mapKey = "time", mapValue = ./time.dhall }
      , { mapKey = "blk", mapValue = ./blk.dhall }
      , { mapKey = "net", mapValue = ./net.dhall }
      , { mapKey = "net_2if", mapValue = ./net_2if.dhall }
      ]

in  Test::{ children = tests }