-- SPDX-License-Identifier: CC0-1.0
let Genode = env:DHALL_GENODE

let Args =
        { config : Genode.Init.Type
        , rom : Genode.Prelude.Map.Type Text Genode.Boot.Rom
        }
      : Type

in    λ(args : Args)
    → { config =
          Genode.Init::{
          , verbose = True
          , defaultRoutes =
                Genode.Init.default.defaultRoutes
              # [ Genode.ServiceRoute.child "Timer" "timer" ]
          , children =
              [ { mapKey = "timer"
                , mapValue =
                    Genode.Init.Start::{
                    , binary = "linux_timer_drv"
                    , resources = { caps = 96, ram = Genode.units.MiB 1 }
                    , provides = [ "Timer" ]
                    }
                }
              , { mapKey = "test", mapValue = Genode.Init.toStart args.config }
              ]
          }
      , rom =
          let manifest = env:MANIFEST
          
          in      Genode.Boot.toRomPaths
                    [ manifest.base-linux.bin.ld
                    , manifest.base-linux.bin.linux_timer_drv
                    , manifest.os.bin.init
                    , manifest.base-linux.bin.core-linux
                    ]
                # args.rom
              : Genode.Prelude.Map.Type Text Genode.Boot.Rom
      }