# This file contains overrides necesarry to build some Make and Depot targets.
# Many targets can be built with the default attributes, and are not listed here.

{ buildPackages, ports }:
with ports;
let
  includeDir = pkg: buildPackages.lib.getDev pkg + "/include";

  hostLibcInc = includeDir buildPackages.glibc;
  # TODO: does this need to be glibc?

  vbox5' = {
    nativeBuildInputs = with buildPackages; [ iasl yasm ];
    patches = [ ./vbox-framebuffer-fail-on-fail.patch ];
    portInputs = [ libc libiconv qemu-usb stdcxx virtualbox5 ];
  };
in {

  cached_fs_rom.patches = [ ./cached_fs_rom.patch ];

  fb_sdl = with buildPackages; {
    nativeBuildInputs = [ pkgconfig ];
    buildInputs = [ SDL ];
    HOST_INC_DIR = [ hostLibcInc (includeDir SDL) ];
  };

  gpt_write.portInputs = [ jitterentropy ];

  init.patches = [ ./sandbox.patch ];

  input_filter.patches = [ ./input_filter.patch ];

  intel_fb_drv = {
    BOARD = "pc";
    portInputs = [ dde_linux ];
  };

  ipxe_nic_drv.portInputs = [ dde_ipxe ];

  libc = {
    portInputs = [ libc ];
    patches = [ ./libc.patch ];
  };

  libiconv.portInputs = [ libc libiconv ];

  linux_nic_drv.HOST_INC_DIR = [ hostLibcInc ];

  lx_block.HOST_INC_DIR = [ hostLibcInc ];

  noux.portInputs = [ libc ];

  posix.portInputs = [ libc ];

  rtc_drv.meta.platforms = [ "x86_64-genode" ];

  rump = {
    portInputs = [ dde_rump ];
    buildInputs = with buildPackages; [ zlib ];
  };

  stdcxx.portInputs = [ libc stdcxx ];

  # The following are tests are patched to exit at completion

  "test-log".patches = [ ./test-log.patch ];

  "test-pci".patches = [ ./test-pci.patch ];

  "test-signal".patches = [ ./test-signal.patch ];

  "test-vmm_x86".patches = [ ./test-vmm_x86.patch ];

  usb_drv.portInputs = [ dde_linux ];

  vbox5 = vbox5';

  vbox5-nova = vbox5';

  vesa_drv.portInputs = [ libc x86emu ];

  vfs.outputs = [ "out" "lib" ];

  vfs_import.patches = [ ./vfs_import.patch ];
  vfs_jitterentropy.portInputs = [ jitterentropy libc ];
  vfs_lwip.portInputs = [ lwip ];
  vfs_ttf.portInputs = [ libc stb ];

  wifi_drv.portInputs = [ dde_linux libc openssl ];

}