# SPDX-FileCopyrightText: 2003-2020 Nixpkgs/NixOS contributors
#
# SPDX-License-Identifier: MIT

{ stdenv, cmake, fetch, libcxx, libunwind, llvm, version
, enableShared ? true }:

let
  enableShared' = enableShared -> !stdenv.hostPlatform.isGenode;
in
stdenv.mkDerivation {
  pname = "libc++abi";
  inherit version;

  src = fetch "libcxxabi" "1vznz8n1z1h8af0ga451m98lc2hjnv4fyzl71napsvjhvk4g6nxp";

  nativeBuildInputs = [ cmake ];
  buildInputs = stdenv.lib.optional (!stdenv.isDarwin && !stdenv.isFreeBSD && !stdenv.hostPlatform.isGenode && !stdenv.hostPlatform.isWasm) libunwind;

  cmakeFlags = stdenv.lib.optionals (stdenv.hostPlatform.useLLVM or false) [
    "-DLLVM_ENABLE_LIBCXX=ON"
    "-DLIBCXXABI_USE_LLVM_UNWINDER=ON"
  ] ++ stdenv.lib.optionals stdenv.hostPlatform.isWasm [
    "-DLIBCXXABI_ENABLE_THREADS=OFF"
    "-DLIBCXXABI_ENABLE_EXCEPTIONS=OFF"
  ] ++ stdenv.lib.optionals (!enableShared') [
    "-DLIBCXXABI_ENABLE_SHARED=OFF"
  ] ++ stdenv.lib.optionals stdenv.hostPlatform.isGenode [
      "-DCMAKE_C_FLAGS=-nodefaultlibs"
      "-DLIBCXXABI_ENABLE_THREADS=OFF"
      "-DLIBCXXABI_BAREMETAL=ON"
      "-DLIBCXXABI_ENABLE_STATIC_UNWINDER=ON"
    ];

  patches = [
    ./libcxxabi-no-threads.patch
  ];

  postUnpack = ''
    unpackFile ${libcxx.src}
    unpackFile ${llvm.src}
    cmakeFlags+=" -DLLVM_PATH=$PWD/$(ls -d llvm-*) -DLIBCXXABI_LIBCXX_PATH=$PWD/$(ls -d libcxx-*)"
  '' + stdenv.lib.optionalString stdenv.isDarwin ''
    export TRIPLE=x86_64-apple-darwin
  '' + stdenv.lib.optionalString stdenv.hostPlatform.isMusl ''
    patch -p1 -d $(ls -d libcxx-*) -i ${../libcxx-0001-musl-hacks.patch}
  '' + stdenv.lib.optionalString stdenv.targetPlatform.isGenode ''
    patch -p1 -d $(ls -d llvm-*) -i ${./llvm-genode.patch}
  '' + stdenv.lib.optionalString stdenv.hostPlatform.isWasm ''
    patch -p1 -d $(ls -d llvm-*) -i ${./libcxxabi-wasm.patch}
  '';

  installPhase = if stdenv.isDarwin
    then ''
      for file in lib/*.dylib; do
        # this should be done in CMake, but having trouble figuring out
        # the magic combination of necessary CMake variables
        # if you fancy a try, take a look at
        # http://www.cmake.org/Wiki/CMake_RPATH_handling
        install_name_tool -id $out/$file $file
      done
      make install
      install -d 755 $out/include
      install -m 644 ../include/*.h $out/include
    ''
    else ''
      install -d -m 755 $out/include $out/lib
      install -m 644 lib/libc++abi.a $out/lib
      install -m 644 ../include/*.h $out/include
    '' + stdenv.lib.optionalString enableShared' ''
      install -m 644 lib/libc++abi.so.1.0 $out/lib
      ln -s libc++abi.so.1.0 $out/lib/libc++abi.so
      ln -s libc++abi.so.1.0 $out/lib/libc++abi.so.1
    '';

  meta = {
    homepage = http://libcxxabi.llvm.org/;
    description = "A new implementation of low level support for a standard C++ library";
    license = with stdenv.lib.licenses; [ ncsa mit ];
    maintainers = with stdenv.lib.maintainers; [ vlstill ];
    platforms = stdenv.lib.platforms.all;
  };
}