genodepkgs/pkgs/solo5/default.nix

# SPDX-FileCopyrightText: Emery Hemingway
#
# SPDX-License-Identifier: LicenseRef-Hippocratic-1.1

{ stdenv, buildPackages, fetchurl, llvmPackages }:

let version = "0.6.3";
in stdenv.mkDerivation {
  pname = "solo5";
  inherit version;

  outputs = [ "out" "tests" ];

  src = fetchurl {
    url = "https://github.com/Solo5/solo5/releases/download/v${version}/solo5-v${version}.tar.gz";
    sha256 = "08z2gv0jlsq6r92vacapdj0hqhyfqfy3xdjn5k9c1pd23a2syq7w";
  };

  enableParallelBuilding = true;

  configurePhase = ''
    runHook preConfigure
    rm -r tests/test_tls
    HOSTCC=${buildPackages.stdenv.cc}/bin/cc sh configure.sh
    runHook postConfigure
  '';

  installPhase = ''
    runHook preInstall
    mkdir -p $out/bin $tests/bin
    make install-opam-genode PREFIX=$out
    for test in tests/*/*.genode; do
      cp $test $tests/bin/solo5-`basename $test .genode`
    done
    runHook postInstall
  '';

  meta = with stdenv.lib; {
    description = "Sandboxed execution environment.";
    homepage = "https://github.com/solo5/solo5";
    license = licenses.isc;
    maintainers = [ maintainers.ehmry ];
  };

}