genodepkgs/overlay/genode/default.nix

{ buildPackages, targetPackages }:
with buildPackages;

let
  version = "20.02";
  genodeSources = let
    platform = targetPackages.targetPlatform;

    arch = with platform;
      if isx86_64 then
        "x86_64"
      else
        throw "unknown Genode arch for platform ${platform.system}";

    toolPrefix = if platform.isx86 then
      "genode-x86-"
    else
      throw "unknown tool prefix for Genode arch ${arch}";
  in stdenvNoCC.mkDerivation {
    pname = "genode-sources";
    inherit version;
    src = fetchurl {
      url = "https://github.com/genodelabs/genode/archive/${version}.tar.gz";
      hash = "sha256-ZY9ND6vDA9u127TAv87uOjPuLzRzBPyp5PzD6iM7uNI=";
    };

    nativeBuildInputs = [ expect gnumake tcl ];
    patches = [ ./init.xsd.patch ./svn-trust-server-cert.patch ];
    configurePhase = ''
      patchShebangs ./tool
      substituteInPlace repos/base/etc/tools.conf \
        --replace "/usr/local/genode/tool/19.05/bin/" ""
      substituteInPlace tool/check_abi \
        --replace "exec nm" "exec ${toolPrefix}nm"
    '';
    dontBuild = true;
    installPhase = "cp -a . $out";
  };

  sourceForgeToolchain = callPackage ./toolchain.nix { };

  stdenv' = targetPackages.stdenvAdapters.overrideCC targetPackages.stdenv
    sourceForgeToolchain;

  platform = stdenv'.targetPlatform;

  arch = with platform;
    if isx86_64 then
      "x86_64"
    else
      throw "unknown Genode arch for platform ${platform.system}";

  preparePort = name:
    { hash ? "sha256-AAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAA=", ... }@args:
    stdenvNoCC.mkDerivation (args // {
      outputHashMode = "recursive";
      outputHash = hash;
      pname = name;
      inherit (genodeSources) version;

      GIT_SSL_CAINFO = "${cacert}/etc/ssl/certs/ca-bundle.crt";
      VERBOSE = "";
      # need to build in verbose mode because errors are hidden

      impureEnvVars = stdenv'.lib.fetchers.proxyImpureEnvVars
        ++ [ "GIT_PROXY_COMMAND" "SOCKS_SERVER" ];

      dontUnpack = true;
      dontConfigure = true;

      nativeBuildInputs =
        [ bison flex gitMinimal glibc glibcLocales rsync wget which ]
        ++ (args.nativeBuildInputs or [ ]);

      buildPhase = ''
        runHook preBuild
        export CONTRIB_DIR=$NIX_BUILD_TOP/contrib
        mkdir $CONTRIB_DIR
        ${genodeSources}/tool/ports/prepare_port $pname
        runHook postBuild
      '';

      installPhase = ''
        runHook preInstall
        rsync $CONTRIB_DIR/* $out/ \
          -lr --copy-unsafe-links \
          --exclude '*.git' \
          --exclude '*.svn' \
          --exclude '*.gz' \
          --exclude '*.xz' \

        runHook postInstall
      '';
    });

  ports = stdenv.lib.mapAttrs preparePort
    (import ./ports.nix { inherit buildPackages; });

  buildUpstream = { name, targets, portInputs ? [ ], nativeBuildInputs ? [ ]
    , ... }@extraAttrs:

    let
      drv = stdenv'.mkDerivation (extraAttrs // {
        pname = name;
        inherit (genodeSources) version;
        inherit targets;

        dontUnpack = true;

        nativeBuildInputs = [ binutils bison flex stdenv.cc tcl which ]
          ++ nativeBuildInputs;

        enableParallelBuilding = true;

        configurePhase = let
          linkPorts = toString
            (builtins.map (drv: " ln -sv ${drv}/* contrib/;") portInputs);
        in ''
          runHook preConfigure
          export CONTRIB_DIR=$NIX_BUILD_TOP/contrib
          export BUILD_DIR=$NIX_BUILD_TOP/build
          ${genodeSources}/tool/create_builddir ${arch}
          substituteInPlace build/etc/build.conf \
            --replace "#REPOSITORIES" "REPOSITORIES"
          mkdir $CONTRIB_DIR; ${linkPorts}
          runHook postConfigure
        '';

        makeFlags = [ "-C build" ] ++ targets;

        installPhase = ''
          runHook preInstall
          find build/bin -name '*.xsd' -delete
          find build/bin -follow -type f -exec install -Dt $out '{}' \;
          runHook postInstall
        '';
      });
    in drv;

  buildOverrides = callPackage ./targets.nix { inherit ports; };

in genodeSources // {
  inherit buildUpstream;
  inherit ports;
  toolchain = sourceForgeToolchain;
  make = target:
    with builtins;
    let
      attrs = if hasAttr target buildOverrides then
        getAttr target buildOverrides
      else
        { };
    in buildUpstream ({
      name = replaceStrings [ "/" ] [ "-" ] target;
      targets = [ target ];
    } // attrs);
}