genodepkgs/packages.nix

# SPDX-FileCopyrightText: Emery Hemingway
#
# SPDX-License-Identifier: LicenseRef-Hippocratic-1.1

let
  nativeOverlay = self: super:
    # Overlay of locally defined packages
    with self;
    let
      genode = (callPackage ./upstream { } // {
        libc = callPackage ./pkgs/libc { };
        nic_bus = callPackage ./pkgs/nic_bus { };
      });
      dhallPackages = super.dhallPackages // (callPackage ./dhall { });
    in {
      genode-base = genode.base;
      genode-base-linux = genode.base-linux;
      genode-base-nova = genode.base-nova;
      genode-os = genode.os;
      depot = callPackage ./depot { };
      dhallGenode = dhallPackages.genode;
      dhallPrelude = dhallPackages.prelude;
      nova = callPackage ./NOVA { };
      solo5 = callPackage ./pkgs/solo5 { };
    };

  toolchainOverlay = import ./toolchain-overlay;
  # Overlay of toolchain patches

in { nixpkgs ? import <nixpkgs>, extraOverlays ? [ ] }:

nixpkgs {
  # Evaluate an overlayed Nixpkgs for a Genode target
  localSystem = "x86_64-linux";
  crossSystem = "x86_64-genode";
  overlays = [ toolchainOverlay nativeOverlay ] ++ extraOverlays;
}