genodepkgs/tests/default.nix

# SPDX-FileCopyrightText: Emery Hemingway
#
# SPDX-License-Identifier: LicenseRef-Hippocratic-1.1

let
  tests = call: {
    fs_report = call ./fs_report.nix { };
    libc = call ./libc.nix { };
    log = call ./log.nix { };
    signal = call ./signal.nix { };
    # solo5 = call ./solo5 { };
  };

in { self, genodepkgs, nixpkgs, dhall-haskell, genode-depot }:

let
  hostPkgs = import nixpkgs {
    system = "x86_64-linux";
    overlays = [ (self: super: { inherit (dhall-haskell.packages) dhall; }) ];
  };
  depot = genode-depot.packages.x86_64-genode;
  testPkgs = genodepkgs;

  lib = hostPkgs.lib // self.lib;

  linux = tests (import ./driver-linux.nix {
    inherit testPkgs hostPkgs lib depot;
  }).callTest;

  nova = (call: ((tests call) // { pci = call ./pci.nix { }; }))
    (import ./driver-nova.nix {
      inherit testPkgs hostPkgs lib depot;
    }).callTest;

  testsToList = tests:
    map (test: {
      inherit (test) name;
      value = test;
    }) (builtins.attrValues tests);

in with builtins; listToAttrs (concatLists (map (testsToList) [ linux nova ]))