109 lines
3.0 KiB
ArmAsm
109 lines
3.0 KiB
ArmAsm
/*-
|
|
* Copyright (c) 2014 Andrew Turner
|
|
* Copyright (c) 2014 The FreeBSD Foundation
|
|
* All rights reserved.
|
|
*
|
|
* Portions of this software were developed by Andrew Turner
|
|
* under sponsorship from the FreeBSD Foundation
|
|
*
|
|
* Redistribution and use in source and binary forms, with or without
|
|
* modification, are permitted provided that the following conditions
|
|
* are met:
|
|
* 1. Redistributions of source code must retain the above copyright
|
|
* notice, this list of conditions and the following disclaimer.
|
|
* 2. Redistributions in binary form must reproduce the above copyright
|
|
* notice, this list of conditions and the following disclaimer in the
|
|
* documentation and/or other materials provided with the distribution.
|
|
*
|
|
* THIS SOFTWARE IS PROVIDED BY THE AUTHOR AND CONTRIBUTORS ``AS IS'' AND
|
|
* ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
|
|
* IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
|
|
* ARE DISCLAIMED. IN NO EVENT SHALL THE AUTHOR OR CONTRIBUTORS BE LIABLE
|
|
* FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
|
|
* DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
|
|
* OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
|
|
* HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
|
|
* LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
|
|
* OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
|
|
* SUCH DAMAGE.
|
|
*
|
|
*/
|
|
|
|
/* needed parts from <machine/asm.h> */
|
|
#define __FBSDID(x)
|
|
#define ENTRY(sym) .text; .globl sym; .align 2; .type sym,#function; sym:
|
|
#define END(sym) .size sym, . - sym
|
|
/* end of <machine/asm.h> */
|
|
|
|
__FBSDID("$FreeBSD: releng/12.0/lib/libc/aarch64/gen/setjmp.S 313146 2017-02-03 11:51:06Z andrew $");
|
|
|
|
/* needed parts from <machine/setjmp.h> */
|
|
#define _JB_SIGMASK 22
|
|
#define _JB_MAGIC__SETJMP 0xfb5d25837d7ff700
|
|
/* end of <machine/asm.h> */
|
|
|
|
ENTRY(setjmp)
|
|
/* Store the magic value and stack pointer */
|
|
ldr x8, .Lmagic
|
|
mov x9, sp
|
|
stp x8, x9, [x0], #16
|
|
|
|
/* Store the general purpose registers and lr */
|
|
stp x19, x20, [x0], #16
|
|
stp x21, x22, [x0], #16
|
|
stp x23, x24, [x0], #16
|
|
stp x25, x26, [x0], #16
|
|
stp x27, x28, [x0], #16
|
|
stp x29, lr, [x0], #16
|
|
|
|
#ifndef _STANDALONE
|
|
/* Store the vfp registers */
|
|
stp d8, d9, [x0], #16
|
|
stp d10, d11, [x0], #16
|
|
stp d12, d13, [x0], #16
|
|
stp d14, d15, [x0]
|
|
#endif
|
|
|
|
/* Return value */
|
|
mov x0, #0
|
|
ret
|
|
.align 3
|
|
.Lmagic:
|
|
.quad _JB_MAGIC__SETJMP
|
|
END(setjmp)
|
|
|
|
ENTRY(longjmp)
|
|
/* Check the magic value */
|
|
ldr x8, [x0], #8
|
|
ldr x9, .Lmagic
|
|
cmp x8, x9
|
|
b.ne botch
|
|
|
|
/* Restore the stack pointer */
|
|
ldr x8, [x0], #8
|
|
mov sp, x8
|
|
|
|
/* Restore the general purpose registers and lr */
|
|
ldp x19, x20, [x0], #16
|
|
ldp x21, x22, [x0], #16
|
|
ldp x23, x24, [x0], #16
|
|
ldp x25, x26, [x0], #16
|
|
ldp x27, x28, [x0], #16
|
|
ldp x29, lr, [x0], #16
|
|
|
|
#ifndef _STANDALONE
|
|
/* Restore the vfp registers */
|
|
ldp d8, d9, [x0], #16
|
|
ldp d10, d11, [x0], #16
|
|
ldp d12, d13, [x0], #16
|
|
ldp d14, d15, [x0]
|
|
#endif
|
|
|
|
/* Load the return value */
|
|
mov x0, x1
|
|
ret
|
|
|
|
botch:
|
|
b botch
|
|
END(longjmp)
|