genode/default.nix

let
  pinnedNixpkgs = import (builtins.fetchGit {
    url = "https://gitea.c3d2.de/ehmry/nixpkgs.git";
    ref = "genode";
  });
in { localSystem ? "x86_64-linux", crossSystem ? "x86_64-genode"
, nixpkgs ? pinnedNixpkgs, self ? { } }:

let
  nixpkgs' = if builtins.isAttrs nixpkgs then
    nixpkgs
  else
    nixpkgs { inherit localSystem crossSystem; };

  inherit (nixpkgs') buildPackages llvmPackages;

  sourceForgeToolchain = nixpkgs'.buildPackages.callPackage ./toolchain.nix { };

  stdenvLlvm = let inherit (nixpkgs') stdenv;
  in assert stdenv.cc.isClang; stdenv;

  stdenvGcc = let
    stdenv =
      nixpkgs'.stdenvAdapters.overrideCC nixpkgs'.stdenv sourceForgeToolchain;
  in assert stdenv.cc.isGNU; stdenv;

  src = self.outPath or (builtins.fetchGit ./.);
  version = self.lastModified or "unstable";

  inherit (stdenvLlvm) lib targetPlatform;
  specs = with targetPlatform;
    [ ]

    ++ lib.optional is32bit "32bit"

    ++ lib.optional is64bit "64bit"

    ++ lib.optional isAarch32 "arm"

    ++ lib.optional isAarch64 "arm_64"

    ++ lib.optional isRiscV "riscv"

    ++ lib.optional isx86 "x86"

    ++ lib.optional isx86_32 "x86_32"

    ++ lib.optional isx86_64 "x86_64";

  toTupConfig = stdenv: attrs:
    let
      tupArch = with stdenv.targetPlatform;

        if isAarch32 then
          "arm"
        else

        if isAarch64 then
          "arm64"
        else

        if isx86_32 then
          "i386"
        else

        if isx86_64 then
          "x86_64"
        else

          abort "unhandled targetPlatform";

      attrs' = with stdenv; { TUP_ARCH = tupArch; } // attrs;
    in nixpkgs'.writeTextFile {
      name = "tup.config";
      text = with builtins;
        let
          op = config: name: ''
            ${config}CONFIG_${name}=${getAttr name attrs}
          '';
        in foldl' op "" (attrNames attrs);
    };

  tupConfigGcc = let
    f = stdenv:
      let prefix = bin: "${stdenv.cc}/bin/${stdenv.cc.targetPrefix}${bin}";
      in {
        AR = prefix "ar";
        CC = prefix "gcc";
        CXX = prefix "g++";
        LD = prefix "ld";
        NM = prefix "nm";
        OBJCOPY = prefix "objcopy";
        OBJDUMP = prefix "objdump";
        RANLIB = prefix "ranlib";
        READELF = prefix "readelf";
        STRIP = prefix "strip";
        PKGCONFIG = "${nixpkgs'.buildPackages.pkgconfig}/bin/pkg-config";

        IS_GCC = "";
        LINUX_HEADERS = buildPackages.glibc.dev;
        VERSION = version;
      };
  in toTupConfig stdenvGcc (f stdenvGcc);

  tupConfigLlvm = let
    f = stdenv:
      let prefix = bin: "${stdenv.cc}/bin/${stdenv.cc.targetPrefix}${bin}";
      in {
        AR = prefix "ar";
        CC = prefix "cc";
        CXX = prefix "c++";
        LD = prefix "ld";
        NM = prefix "nm";
        OBJCOPY = prefix "objcopy";
        OBJDUMP = prefix "objdump";
        RANLIB = prefix "ranlib";
        READELF = prefix "readelf";
        STRIP = prefix "strip";
        PKGCONFIG = "${nixpkgs'.buildPackages.pkgconfig}/bin/pkg-config";

        IS_LLVM = "";
        LIBCXXABI = llvmPackages.libcxxabi;
        LIBCXX = llvmPackages.libcxx;
        LIBUNWIND_BAREMETAL =
          llvmPackages.libunwind.override { isBaremetal = true; };
        LIBUNWIND = llvmPackages.libunwind;
        LINUX_HEADERS = buildPackages.glibc.dev;
        VERSION = version;
      };
  in toTupConfig stdenvLlvm (f stdenvLlvm);

  buildRepo = { stdenv, repo, repoInputs }:
    let

    in stdenv.mkDerivation {
      pname = "genode-" + repo;
      inherit src repo specs version;

      setupHook = ./setup-hooks.sh;

      nativeBuildInputs = repoInputs;
      # This is wrong, why does pkg-config not collect buildInputs?

      propagatedNativeBuildInputs = repoInputs;

      depsBuildBuild = with buildPackages; [ llvm pkgconfig tup ];

      tupConfig = if stdenv.cc.isGNU then
        tupConfigGcc
      else if stdenv.cc.isClang then
        tupConfigLlvm
      else
        throw "no Tup config for this stdenv";

      configurePhase = ''
        # Configure Tup
        set -v
        install -m666 $tupConfig tup.config
        echo CONFIG_NIX_OUTPUTS_OUT=$out >> tup.config
        echo CONFIG_NIX_OUTPUTS_DEV=$out >> tup.config

        # Disable other repos
        for R in repos/*; do
          [ "$R" != "repos/$repo" ] && find $R -name Tupfile -delete
        done

        # Scan repository and generate script
        tup init
        tup generate buildPhase.sh

        # Redirect artifacts to Nix store
        mkdir -p $out/lib $out/include
        ln -s $out out
        ln -s $out dev
      '';

      buildPhase = ''
        test -d repos/$repo/src/ld && cp -rv repos/$repo/src/ld $out/
        pushd .
        set -v
        source buildPhase.sh
        set +v
        popd
      '';

      installPhase = ''
        # Populate the "dev" headers
        if [ -d "repos/$repo/include" ]; then
          for DIR in repos/$repo/include; do
            for SPEC in $specs; do
              if [ -d $DIR/spec/$SPEC ]; then
                cp -r $DIR/spec/$SPEC/* $out/include
                rm -r $DIR/spec/$SPEC
              fi
            done
            rm -rf $DIR/spec
            cp -r $DIR $out/
          done
        fi

        touch $out/.genode
        for pc in $out/lib/pkgconfig/*.pc; do
          sed -e "s|^Libs: |Libs: -L$out/lib |" -i $pc
        done
      '';

      meta = with stdenv.lib; {
        description =
          "The Genode operation system framework (${repo} repository).";
        homepage = "https://genode.org/";
        license = licenses.agpl3;
        maintainers = [ maintainers.ehmry ];
      };

    };

  buildRepo' = { ... } @ args: buildRepo ({ stdenv = stdenvGcc; } // args);

in rec {
  base = buildRepo' {
    repo = "base";
    repoInputs = [ ];
  };

  base-linux = buildRepo' {
    repo = "base-linux";
    repoInputs = [ base ];
  };

  base-nova = buildRepo' {
    repo = "base-nova";
    repoInputs = [ base ];
  };

  os = buildRepo' {
    repo = "os";
    repoInputs = [ base ];
  };

  gems = buildRepo' {
    repo = "gems";
    repoInputs = [ os ];
  };

  inherit stdenvGcc stdenvLlvm tupConfigGcc tupConfigLlvm;
}