blobsets/tests/test_set.nim

import std/unittest, std/os, std/parseopt

import ../src/blobsets

suite "Blob set tests":

  var
    store = newNullStore()
    randomCid = blobHash("")

 # test "zero blob":
 #   doAssert(randomCid == zeroChunk)

  proc randomize() =
    randomCid = blobHash(randomCid.toHex)

  proc testPath(s: BlobSet; root: string): BlobSet =
    for path in walkDirRec(root):
      randomize()
      let
        blob = randomCid
        str = $randomCid
      doAssert(str.toBlobid == randomCid)
      result = insert(store, s, path, blob, 0)
      let found = search(store, result, path)
      doAssert(found == randomCid)

  test "functional insert":
    let
      a = newBlobSet()
      b = insert(store, a, "foo", randomCid, 0)
      c = insert(store, b, "bar", randomCid, 0)
    doAssert(contains(store, b, "foo"))
    doAssert(contains(store, c, "foo"))
    doAssert(contains(store, c, "bar"))
    doAssert(not contains(store, a, "foo"))
    doAssert(not contains(store, a, "bar"))
    doAssert(not contains(store, b, "bar"))

  test "apply":
    var bs = newBlobSet()
    for i in 1..1024:
      let
        name = $i
        blob = blobHash name
      bs = insert(store, bs, name, blob, 0)
    for i in 1..1024:
      let
        name = $i
        blob = blobHash name
        other = search(store, bs, name)
      doAssert(other == blob)

  test "remove":
    var bs = newBlobSet()
    for i in 1..1024:
      let
        name = $i
        blob = blobHash name
      bs = insert(store, bs, name, blob, 0)
    for i in 1..1024:
      let name = $i
      bs = remove(store, bs, name)
      doAssert(not contains(store, bs, name))

  test "sets":
    var s = newBlobSet()
    for kind, key, val in getopt():
      if kind == cmdArgument:
        s = s.testPath(key)
    if s.isEmpty:
      s = s.testPath(".")