scrapers/default.nix

{ pkgs ? import <nixpkgs> {} }:

with pkgs;

let
  gems = bundlerEnv rec {
    name = "scrapers";

    inherit ruby;
    # expects Gemfile, Gemfile.lock and gemset.nix in the same directory
    # > nix-shell -p bundler --run 'bundle lock --update'
    # > nix-shell -p bundix --run bundix
    gemdir = ./.;
  };
  wrapScript = name: script:
    stdenv.mkDerivation {
      inherit name script;
      buildInputs = [ gems.wrappedRuby ];

      buildCommand = ''
        install -D -m755 ${script} $out/bin/${name}
        patchShebangs $out/bin/${name}
      '';
    };
in {
  xerox = wrapScript "xerox" ./xerox/scrape.rb;
  luftdaten = wrapScript "luftdaten" ./luftdaten/scrape.rb;
  luftqualitaet = wrapScript "luftqualitaet" ./luftqualitaet/scrape.rb;
  fhem = wrapScript "fhem" ./fhem/scrape.rb;
  matemat = wrapScript "matemat" ./matemat/scrape.rb;
  freifunk_node = wrapScript "freifunk_node" ./freifunk_node/scrape.rb;
  impfee = wrapScript "impfee" ./impfee/scrape.rb;
  riesa-efau-kalender = wrapScript "riesa-efau-kalender" ./riesa-efau-kalender/scrape.rb;
  kreuzchor-termine = wrapScript "kreuzchor-termine" ./kreuzchor-termine/scrape.rb;
  dhmd-veranstaltungen = wrapScript "dhmd-veranstaltungen" ./dhmd-veranstaltungen/scrape.rb;
  mkz-programm = wrapScript "mkz-programm" ./mkz-programm/scrape.rb;
  drk-impfaktionen = wrapScript "drk-impfaktionen" ./drk-impfaktionen/scrape.rb;
  zuendstoffe = wrapScript "zuendstoffe" ./zuendstoffe/scrape.rb;
  dresden-versammlungen = wrapScript "dresden-versammlungen" ./zuendstoffe/scrape.rb;
}