{ nixos-unstable }:

final: prev:

let
  pkgs-unstable = nixos-unstable.legacyPackages.${prev.system};
in
{
  bmxd = prev.callPackage ./bmxd.nix { };

  dump1090-influxdb = import ./dump1090-influxdb { pkgs = prev; };

  dump1090_rs = prev.callPackage ./dump1090_rs.nix { };

  chromium = prev.chromium.override {
    commandLineArgs = "--enable-features=VaapiVideoEncoder,VaapiVideoDecoder,CanvasOopRasterization --force-dark-mode";
  };

  # hydra flake
  hydra = prev.hydra.overrideAttrs (oldAttrs: with final; {
    patches = oldAttrs.patches or [ ] ++ [
      # gitea webhook support
      (fetchpatch {
        url = "https://github.com/NixOS/hydra/pull/1227/commits/750978a19232583e17620a1bd80435e957e7213a.patch";
        sha256 = "sha256-86Li0YUSVUdnw6lt6kZ56ohDRKPD13SZzukqPU1np8U=";
      })
      # fix github webhook from orgs
      (fetchpatch {
        url = "https://github.com/NixOS/hydra/commit/4d664ecb0faaf51b21673f979b543ea4694c3f1b.patch";
        sha256 = "sha256-lF5Rnz8r9ptyMLhcg/XnjiNhOK1KcLA7hi01ye4KgmI=";
      })
    ];
  });

  # hydra in nixpkgs
  hydra_unstable = prev.hydra_unstable.overrideAttrs (oldAttrs: with final; {
    patches = oldAttrs.patches or [ ] ++ [
      # gitea webhook support
      (fetchpatch {
        url = "https://github.com/NixOS/hydra/pull/1227/commits/750978a19232583e17620a1bd80435e957e7213a.patch";
        sha256 = "sha256-86Li0YUSVUdnw6lt6kZ56ohDRKPD13SZzukqPU1np8U=";
      })
      # fix github webhook from orgs
      (fetchpatch {
        url = "https://github.com/NixOS/hydra/commit/4d664ecb0faaf51b21673f979b543ea4694c3f1b.patch";
        sha256 = "sha256-lF5Rnz8r9ptyMLhcg/XnjiNhOK1KcLA7hi01ye4KgmI=";
      })
    ];
  });

  mlat-client = prev.python3Packages.callPackage ./mlat-client.nix { };

  pile = prev.callPackage ./pile.nix { };

  pi-sensors = prev.callPackage ./pi-sensors { };

  plume = prev.callPackage ./plume { };

  readsb = prev.callPackage ./readsb.nix { };

  SimpleYggGen-CPP = prev.callPackage ./simpleygggen.nix { };

  # TODO: pending https://github.com/NixOS/nixpkgs/pull/186847
  nomad_1_3 = with prev; nomad_1_3.override {
    buildGoModule = buildGo118Module;
    callPackage = f: _: prev.callPackage f {
      buildGoModule = buildGo118Module;
      version = "1.3.3";
      sha256 = "sha256-/63QGknivXyBel2MhMzbh/rE+UrfV3mb+zPZzOU15WU=";
      vendorSha256 = "sha256-5ubJ6hgpdkZd/hwy+u2S6XgQLD5xmgUnaUqJoLdguBQ=";
      nvidiaGpuSupport = false;
      patchelf = null;
      nvidia_x11 = null;
    };
  };

  wander =
    if prev ? wander
    then builtins.trace "`wander` is now available on stable NixOS. Please remove from overlay!"
      prev.wander
    else pkgs-unstable.wander;

  # vector-0.23 + mqtt-sink
  vector = pkgs-unstable.callPackage ./vector {};
}