nix-config/flake.nix

{
  description = "C3D2 NixOS configurations";

  inputs = {
    nixpkgs.url = "github:nixos/nixpkgs/release-20.09";
    secrets = {
      url = "git+ssh://git@gitea.c3d2.de:2222/c3d2-admins/secrets.git";
      flake = false;
    };
  };

  outputs = { self, nixpkgs, secrets }:
    let
      forAllSystems = f:
        nixpkgs.lib.genAttrs [ "aarch64-linux" "x86_64-linux" ]
        (system: f system);
    in {

      inherit (nixpkgs) legacyPackages;

      packages = forAllSystems (system:
        let
          hostRegistry = import ./host-registry.nix;
          pkgs = self.legacyPackages.${system};
          mkDeploy =
            # Generate a small script for copying this flake to the
            # remote machine and bulding and switching there.
            # Can be run with nix run c3d2#deploy-…
            name: host:
            let target = "root@${host}";
            in pkgs.writeScriptBin "${name}-nixos-rebuild" ''
              #!${pkgs.runtimeShell}
              set -ev
              nix-copy-closure --to ${target} ${self}
              exec ssh -t ${target} \
                nix shell \
                  ${self}#nixosConfigurations.${name}.config.system.build.toplevel \
                  --command switch-to-configuration $@
            '';
        in {
          glotzbert-nixos-rebuild = mkDeploy "glotzbert" "glotzbert.hq.c3d2.de";
          glotzbert-wake = pkgs.writeScriptBin "glotzbert-wake" ''
            #!${pkgs.runtimeShell}
            exec ${pkgs.wol}/bin/wol ${hostRegistry.hosts.glotzbert.ether}
          '';
        });

      nixosConfigurations = let
        nixosSystem' =
          # Our custom NixOS builder
          { system ? "x86_64-linux", ... }@args:
          nixpkgs.lib.nixosSystem (args // {
            inherit system;
            extraModules = [
              self.nixosModules.c3d2
              ({ pkgs, ... }: {
                nix = {
                  package = pkgs.nixFlakes;
                  extraOptions = "experimental-features = nix-command flakes";
                };
              })
            ];
          });
      in {

        glotzbert = nixosSystem' { modules = [ ./hosts/glotzbert ]; };

      };

      nixosModules.c3d2 = import ./lib;

    };
}