nix-config/hosts/containers/nncp/default.nix

{ config, lib, pkgs, ... }:

{
  imports = [ ./neighbours.nix ];

  c3d2.mergeNncpSettings = false;
  c3d2.hq.statistics.enable = true;
  c3d2.autoUpdate = true;

  networking = {
    hostName = "nncp";
    firewall.enable = false;
  };

  programs.nncp = {
    enable = true;
    secrets = [ "/etc/nncp.secrets" ];
    settings = {
      mcd-listen = [ "eth0" ];
      mcd-send.eth0 = 60;
      neigh = # use c3d2.nncp.neigh but remove this node
        let
          hourlyCall = {
            cron = "0 42 * * * * *"; # 4:00
            xx = "tx"; # transmit only
            when-tx-exists = true;
          };
        in lib.mapAttrs (name: value:
          value // {
            via = lib.lists.remove "c3d2" value.via;
          } // (lib.attrsets.optionalAttrs (value.addrs or { } != { }) {
            calls = [ hourlyCall ];
          })) (builtins.removeAttrs config.c3d2.nncp.neigh [ "c3d2" ]);
    };
  };

  services.collectd.plugins.exec = let
    util =
      pkgs.runCommand "collectd_nncp" { nativeBuildInputs = [ pkgs.nim ]; } ''
        cp ${./collectd_nncp.nim} ./collectd_nncp.nim
        nim c --nimcache:. -o:$out ./collectd_nncp.nim
      '';
  in ''
    Exec "${config.services.collectd.user}" "${util}" "${config.programs.nncp.settings.spool}"
  '';
  users.groups.uucp.members = [ config.services.collectd.user ];

  services.nncp = {
    caller = {
      enable = true;
      extraArgs = [ "-autotoss" ];
    };
    daemon = {
      enable = true;
      socketActivation.enable = false;
      extraArgs = [ "-autotoss" ];
    };
  };

}