hydra-config/mateamt.nix

{ pkgs ? import <nixpkgs> {}
}:
with pkgs;
let
  mateamtSrc = stdenv.mkDerivation {
    name = "mateamt-src";
    src = <mateamt>;
    phases = [ "unpackPhase" "patchPhase" "installPhase" ];
    patchPhase = ''
      substituteInPlace default.nix \
        --replace \
        "builtins.fetchTarball https://github.com/input-output-hk/haskell.nix/archive/master.tar.gz" \
        "<haskell-nix>"
    '';
    installPhase = "cp -ar . $out";
  };
  mateamt = haskellPackages.callPackage "${mateamtSrc}";
  ghcBlacklist = [
    # "ghc822"
    # "ghc844"
    # "ghc881"
    # "ghcHEAD"
  ];
  ghcVersions =
    builtins.filter (p:
      (p == "ghcHEAD" || builtins.match "ghc[[:digit:]]+" p != null) &&
      (!builtins.elem p ghcBlacklist)
    ) (builtins.attrNames haskell.packages);
in

builtins.listToAttrs
  (map (ghcVersion: {
    name = "mateamt-${ghcVersion}";
    value = lib.hydraJob (mateamt {
      compiler = ghcVersion;
      nixpkgs = pkgs;
    });
  }) ghcVersions)