c3d2-web/xsl/podcast.xsl

<?xml version="1.0" encoding="utf-8"?>

<!-- Spezifikationen:
     https://www.apple.com/itunes/store/podcaststechspecs.html
     XMLNS podcast: https://github.com/Podcastindex-org/podcast-namespace/blob/main/docs/1.0.md
 -->

<xsl:stylesheet version="1.0"
  xmlns:itunes="https://www.itunes.com/dtds/podcast-1.0.dtd"
  xmlns:xsl="https://www.w3.org/1999/XSL/Transform"
  xmlns:date="http://exslt.org/dates-and-times"
  xmlns:content="https://purl.org/rss/1.0/modules/content/" 
  xmlns:atom="https://www.w3.org/2005/Atom"
  xmlns:podcast="https://podcastindex.org/namespace/1.0"
  exclude-result-prefixes="xsl date">

  <xsl:output method="xml"
              version="1.0"
              encoding="utf-8"
              indent="yes"/>

  <xsl:include href="common.xsl" />

  <xsl:variable name="baseurl">https://www.c3d2.de/</xsl:variable>
  <xsl:param name="selection" select="''"/>
  <xsl:param name="format"/>
  <xsl:param name="archivefeed"/>

  <!--xsl:text disable-output-escaping="yes">&lt;?xml-stylesheet type="text/css" href="https://c3d2.de/style/rss.css"?&gt;</xsl:text-->

  <xsl:template match="news">
    <rss version="2.0">

      <channel>
        <xsl:choose>
          <xsl:when test="$selection = 'pentamedia'">
            <title>Penta*</title>
            <link><xsl:value-of select="$baseurl"/></link>
            <description>Pentaradio, Pentacast, Pentamusic</description>
	    <image>
	      <title>Pentaradio</title>
	      <url><xsl:value-of select="$baseurl"/>images/pentaradio-artwork.png</url>
	      <link><xsl:value-of select="$baseurl"/>radio.html</link>
	    </image>

            <itunes:subtitle>Die drei Podcasts vom CCC Dresden</itunes:subtitle>
            <itunes:summary>
	      Enthält Podcasts von Pentaradio, Pentacast und Pentamusic
            </itunes:summary>
            <itunes:image href="{$baseurl}images/pentaradio-artwork.png" />
            <itunes:category text="Society &amp; Culture"/>
            <itunes:category text="Technology">
              <itunes:category text="Tech News"/>
            </itunes:category>
          </xsl:when>
          <xsl:when test="$selection = 'pentaradio'">
            <title>Pentaradio</title>
            <link><xsl:value-of select="$baseurl"/>radio.html</link>
            <description>C3D2 Pentaradio</description>
	    <image>
	      <title>Pentaradio</title>
	      <url><xsl:value-of select="$baseurl"/>images/pentaradio-artwork.png</url>
	      <link><xsl:value-of select="$baseurl"/>radio.html</link>
	    </image>
            <itunes:subtitle>Radio vom CCC Dresden</itunes:subtitle>
            <itunes:summary>
              Pentaradio sind die Sendungen des Chaos Computer Club Dresden auf coloRadio, bestehend aus einem informativen Rahmenprogramm und Beiträgen zu einem sendungsspezifischen Thema.
            </itunes:summary>
            <itunes:image href="{$baseurl}images/pentaradio-artwork.png" />
            <itunes:category text="Society &amp; Culture"/>
            <itunes:category text="Technology">
              <itunes:category text="Tech News"/>
            </itunes:category>
          </xsl:when>
          <xsl:when test="$selection = 'pentacast'">
            <title>Pentacast</title>
            <link><xsl:value-of select="$baseurl"/>podcast.html</link>
            <description>C3D2 Pentacast</description>
	    <image>
	      <title>Pentacast</title>
	      <url><xsl:value-of select="$baseurl"/>images/pentacast-artwork.png</url>
	      <link><xsl:value-of select="$baseurl"/>podcast.html</link>
	    </image>
            <itunes:subtitle>Podcasts vom CCC Dresden</itunes:subtitle>
            <itunes:summary>
              Pentacast sind themenspezifische Sendungen des Chaos
              Computer Club Dresden.
            </itunes:summary>
            <itunes:image href="{$baseurl}images/pentacast-artwork.png" />
            <itunes:category text="Society &amp; Culture"/>
            <itunes:category text="Technology"/>
          </xsl:when>
          <xsl:when test="$selection = 'pentamusic'">
            <title>Pentamusic</title>
            <link><xsl:value-of select="$baseurl"/>pentamusic.html</link>
            <description>C3D2 Pentamusic</description>
	    <image>
	      <title>Pentamusic</title>
	      <url><xsl:value-of select="$baseurl"/>images/pentamusic-quadratic.png</url>
	      <link><xsl:value-of select="$baseurl"/>pentamusic.html</link>
	    </image>
            <itunes:subtitle>Musikvorstellungen vom CCC Dresden</itunes:subtitle>
            <itunes:summary>
              Versuch, Künstler, Bands und Labels der CC-Szene vors
              Mikro zu holen um diese einer breiteren Öffentlichkeit
              bekannt zu machen.
            </itunes:summary>
            <itunes:image href="{$baseurl}images/pentamusic-quadratic.png" />
            <itunes:category text="Society &amp; Culture"/>
            <itunes:category text="Music"/>
          </xsl:when>
          <xsl:otherwise>
            <title>C3D2 Podcast</title>
            <link><xsl:value-of select="$baseurl"/></link>
            <description>C3D2 Podcast</description>
	    <image>
	      <title>C3D2</title>
	      <url><xsl:value-of select="$baseurl"/>images/ck.png</url>
	      <link><xsl:value-of select="$baseurl"/></link>
	    </image>
            <itunes:subtitle>Radio &amp; Podcasts vom CCC Dresden</itunes:subtitle>
            <itunes:summary>
              Pentaradio, Pentacast &amp; Pentamusic vom Chaos Computer Club Dresden.
            </itunes:summary>
            <itunes:image href="{$baseurl}images/ck.png" />
            <itunes:category text="Society &amp; Culture"/>
            <itunes:category text="Technology"/>
          </xsl:otherwise>
        </xsl:choose>
		<language>de</language>
		<copyright>https://creativecommons.org/licenses/by-sa/2.0/de/</copyright>
        <itunes:author>Chaos Computer Club Dresden</itunes:author>
        <itunes:owner>
          <itunes:name>C3D2</itunes:name>
          <itunes:email>podcast@c3d2.de</itunes:email>
        </itunes:owner>
        <itunes:explicit>no</itunes:explicit>

        <!--generator>C3D2 custom XSLT</generator-->
        <!--lastBuildDate>
          <xsl:call-template name="date-to-rfc822">
            <xsl:with-param name="date" select="$builddate"/>
          </xsl:call-template>
        </lastBuildDate-->
        <podcast:locked owner="mail@c3d2.de">no</podcast:locked>
        <podcast:funding url="https://c3d2.de/unterstuetzen.html">C3D2 Unterstützen!</podcast:funding>
        <podcast:funding url="c3d2.de/membership.html">Mitglied werden!</podcast:funding>
        <podcast:location geo="geo:51.08106,13.72867">C3D2, Dresden, Germany</podcast:location>
        <podcast:license url="https://creativecommons.org/licenses/by-sa/2.0/de/">CC BY-SA 2.0 DE</podcast:license>
        <!-- experimental part -->
        <podcast:value type="bitcoin" method="default" suggested="0.00000001">
          <podcast:valueRecipient name="C3D2" type="bech32" address="bitcoin:BC1QANU4755ULAU2JJDQSJLC3YW2XDJAWJ8WMVF5LA" fee="true"/>
          <podcast:valueRecipient name="C3D2" type="p2sh" address="bitcoin:3AhYpTzozbxFSmL1NqdZqsFgZhKc95BsCP" fee="true"/>
          <podcast:valueRecipient name="C3D2" type="p2pkh" address="bitcoin:195jSW9hXHdhu5QEeHkhyAN6Kf2oFUkmyK" fee="true"/>
        </podcast:value>
        <podcast:value type="bitcoin" method="bip47" suggested="0.00000001">
          <podcast:valueRecipient name="C3D2" type="bip47" address="bitcoin:PM8TJRmTRWxcrfqwbA1t3KYk555WecaJ7CZJzPoK11R1nE8LuTHebppUysAnqNTX4kLrUyHm7oNPbsjAZrLjmfLdStiNG34iDMNcXqY27j9w7uaFcCah" fee="true"/>
          <podcast:valueRecipient name="C3D2" type="paynym" address="https://paynym.is/+lingeringmouse27c" fee="true"/>
        </podcast:value>
        <podcast:value type="monero" method="default" suggested="0.000001">
          <podcast:valueRecipient name="C3D2" type="monero" address="45c4E14LpNbeTdL8FSuBQA7M3wJ5nxGnYfnEzv3hwasfZUuKwP5zAaDCgJfD3s9kT4GP7y678gi6b1cGSVSgFpsTTm6fPtz" fee="true"/>
        </podcast:value>
        <podcast:value type="wire" method="sepa" suggested="5">
          <podcast:valueRecipient name="C3D2" type="bezahlcode" address="bank://singlepaymentsepa?name=NETZBIOTOP%20DRESDEN%20E.V.&amp;reason=Spende&amp;iban=DE34850900004655221005&amp;bic=GENODEF1DRS&amp;amount="/>
        </podcast:value>
        <!--podcast:value type="lightning" method="keysend" suggested="0.00000005000">
          <podcast:valueRecipient
            name="[name of recipient(string)]"
            type="[address type(string)]"
            address="[the receiving address(string)]"
            customKey="[optional key to pass(mixed)]"
            customValue="[optional value to pass(mixed)]"
            split="[share count(int)]"
            fee=[true|false]
          />
        </podcast:value-->

	<xsl:if test="$archivefeed">
	  <atom:link rel="prev-archive" href="{$archivefeed}"/>
	</xsl:if>

        <xsl:for-each select="newsfile">
          <xsl:sort select="date:seconds(document(.)/item/@date)" data-type="number" order="descending" />
	  <xsl:if test="position() &lt;= $maxitems">
	    <xsl:choose>
	      <xsl:when test="($selection = 'pentaradio' or $selection = 'pentamedia') and
			      starts-with(., 'content/news/pentaradio') and
			      count(document(.)/item//resource) &gt; 0">
		<xsl:apply-templates select="document(.)/item//resource" mode="preselect">
		  <xsl:with-param name="newsfile" select="."/>
		</xsl:apply-templates>
	      </xsl:when>
	      <xsl:when test="($selection = 'pentacast' or $selection = 'pentamedia') and
			      starts-with(., 'content/news/pentacast') and
			      count(document(.)/item//resource) &gt; 0">
		<xsl:apply-templates select="document(.)/item//resource" mode="preselect">
		  <xsl:with-param name="newsfile" select="."/>
		</xsl:apply-templates>
	      </xsl:when>
	      <xsl:when test="($selection = 'pentamusic' or $selection = 'pentamedia') and
			      starts-with(., 'content/news/pentamusic') and
			      count(document(.)/item//resource) &gt; 0">
		<xsl:apply-templates select="document(.)/item//resource" mode="preselect">
		  <xsl:with-param name="newsfile" select="."/>
		</xsl:apply-templates>
	      </xsl:when>
	      <xsl:when test="$selection = '' and count(document(.)/item//resource) &gt; 0">
		<xsl:apply-templates select="document(.)/item//resource" mode="preselect">
		  <xsl:with-param name="newsfile" select="."/>
		</xsl:apply-templates>
	      </xsl:when>
	    </xsl:choose>
	  </xsl:if>
        </xsl:for-each>
      </channel>

    </rss>
  </xsl:template>


  <!-- Preselect heißt:
       * Gucken, ob es in der Resource nicht ein Alternative gibt, welches $format ist
       * Dann dieses nehmen
       * Ansonsten die Resource nehmen
    -->
  <xsl:template match="resource" mode="preselect">
    <xsl:param name="newsfile"/>

    <xsl:choose>
      <!-- Gibts ein $format? -->
      <xsl:when test="count(alternative[contains($format, @type)]) &gt; 0">
        <xsl:apply-templates select="alternative[contains($format, @type)]">
          <xsl:with-param name="newsfile" select="$newsfile"/>
        </xsl:apply-templates>
      </xsl:when>
      <!-- Nimm was da ist -->
      <xsl:otherwise>
        <xsl:apply-templates select=".">
          <xsl:with-param name="newsfile" select="$newsfile"/>
        </xsl:apply-templates>
      </xsl:otherwise>
    </xsl:choose>
  </xsl:template>


  <xsl:template match="*[name() = 'resource' or name() = 'alternative']">
    <xsl:param name="newsfile"/>

    <xsl:variable name="href">
      <xsl:call-template name="make-href">
        <xsl:with-param name="href" select="@url"/>
      </xsl:call-template>
    </xsl:variable>

    <xsl:call-template name="generate-item">
      <xsl:with-param name="newsfile" select="$newsfile"/>
      <xsl:with-param name="item_title">
	<xsl:value-of select="document($newsfile)/item/@title"/>
	<xsl:if test="count(document($newsfile)//resource) &gt; 1 and @title">
	  <!-- Multiple resources in this item? -->
	  <xsl:text>: </xsl:text>
	  <xsl:value-of select="@title"/>
	</xsl:if>
      </xsl:with-param>
      <xsl:with-param name="resource_title">
	<xsl:choose>
	  <xsl:when test="@title"><xsl:value-of select="@title"/></xsl:when>
	  <xsl:otherwise><xsl:value-of select="../@title"/></xsl:otherwise>
	</xsl:choose>
      </xsl:with-param>
      <xsl:with-param name="date" select="document($newsfile)/item/@date"/>
      <xsl:with-param name="resource_url" select="$href"/>
      <xsl:with-param name="resource_size" select="@size"/>
      <xsl:with-param name="resource_type" select="@type"/>
      <xsl:with-param name="chapters" select="sc:chapters"
		      xmlns:sc="https://podlove.de/simple-chapters"/>
    </xsl:call-template>
  </xsl:template>

  <xsl:template name="generate-item">
    <xsl:param name="newsfile"/>
    <xsl:param name="item_title"/>
    <xsl:param name="resource_title"/>
    <xsl:param name="date"/>
    <xsl:param name="resource_url"/>
    <xsl:param name="resource_size"/>
    <xsl:param name="resource_type"/>
    <xsl:param name="chapters"/>

    <item>
      <xsl:variable name="href">
        <xsl:value-of select="$baseurl"/>
        <xsl:value-of select="substring-before(substring-after($newsfile, 'content/'), '.xml')"/>
        <xsl:text>.html</xsl:text>
      </xsl:variable>

      <title><xsl:value-of select="$item_title"/></title>
      <description>
	<xsl:text disable-output-escaping="yes">&lt;![CDATA[</xsl:text>
	<div xmlns="https://www.w3.org/1999/xhtml">
	  <xsl:apply-templates select="document($newsfile)/item/*[name() != 'resource']"/>
	</div>
	<xsl:text disable-output-escaping="yes">]]&gt;</xsl:text>
      </description>
      <link><xsl:value-of select="$href"/></link>

      <enclosure
        url="{$resource_url}"
        length="{$resource_size}"
        type="{$resource_type}"
        />

      <guid isPermaLink="false"><xsl:value-of select="concat($href, '+++', $resource_url)"/></guid>

      <pubDate>
        <xsl:call-template name="date-to-rfc822">
          <xsl:with-param name="date" select="$date"/>
        </xsl:call-template>
      </pubDate>

      <content:encoded>
	<xsl:text disable-output-escaping="yes">&lt;![CDATA[</xsl:text>
	<div xmlns="https://www.w3.org/1999/xhtml">
	  <xsl:apply-templates select="document($newsfile)/item/*[name() != 'resource']"/>
	</div>
	<xsl:text disable-output-escaping="yes">]]&gt;</xsl:text>
      </content:encoded>

      <!-- iTunes-Extensions zum Schluss, sonst validiert es nicht -->

      <itunes:subtitle><xsl:value-of select="$resource_title"/></itunes:subtitle>
      <itunes:author>CCC Dresden</itunes:author>

      <xsl:copy-of select="$chapters"/>

      <!-- XMLNS podcast – https://podcastindex.org/ -->

      <!--podcast:transcript url="concat('',$baseurl,'transcripts/',$resource_url,'.html')" type="text/html"/--><!-- better check for variable and include when not empty -->
      <!--podcast:season name="Egyptology: The 19th Century">1</podcast:season-->
      <!--podcast:episode display="Ch.3">204</podcast:episode-->
      <!--podcast:chapters url="https://example.com/episode1/chapters.json" type="application/json+chapters" /-->
      <!--podcast:soundbite startTime="73.0" duration="60.0">Song</podcast:soundbite-->
      <!--podcast:person href="https://example.com/johnsmith/blog" img="https://example.com/images/johnsmith.jpg">John Smith</podcast:person-->
      <!--podcast:value-->
    </item>
  </xsl:template>

  <xsl:template match="addendum">
    <xsl:apply-templates select="*[name() != 'resource']"/>
  </xsl:template>

</xsl:stylesheet>