caveman/flake.nix

{
  inputs = {
    utils.url = "github:numtide/flake-utils";
    naersk.url = "github:nmattia/naersk";
    naersk.inputs.nixpkgs.follows = "nixpkgs";
    fenix.url = "github:nix-community/fenix";
    fenix.inputs.nixpkgs.follows = "nixpkgs";
  };

  outputs = { self, nixpkgs, utils, fenix, naersk }: {
    # nixosModule = self.nixosModules.caveman;
    # nixosModules.caveman = import ./nixos-module.nix { inherit self; };
  } //
  utils.lib.eachSystem (with utils.lib.system; [ x86_64-linux aarch64-linux ]) (system: let
    pkgs = nixpkgs.legacyPackages.${system};

    rust = fenix.packages.${system}.stable.withComponents [
      "cargo"
      "rustc"
      "rust-src"  # just for rust-analyzer
      "clippy"
    ];

    # Override the version used in naersk
    naersk-lib = naersk.lib."${system}".override {
      cargo = rust;
      rustc = rust;
    };

  in rec {
    packages.default = self.packages.${system}.caveman-hunter;

    packages.caveman-hunter = naersk-lib.buildPackage {
      src = ./hunter;
      nativeBuildInputs = with pkgs; [ pkg-config ];
      buildInputs = with pkgs; [ openssl systemd ];
    };

    # `nix develop`
    devShells.default = pkgs.mkShell {
      nativeBuildInputs = [
        fenix.packages.${system}.rust-analyzer
      ] ++
      (with packages.default; nativeBuildInputs ++ buildInputs);
    };
  });
}